グラフの体裁を一発で整えるExcelマクロ

趣味や仕事の関係上、散布図を作る機会が多く、Excelで散布図を作るたびに体裁を整える（色を変えたり、凡例を付けたり、タイトルを消したり、軸ラベルを付けたり…）のが煩わしく感じていました。
今回は、そんな作業をVBAで処理できるようにしたので、本記事で紹介します。

記事の下部にコードを載せているので、ご自由にお使いください。
プログラムの中身に関するご質問には答えたり答えなかったりしますが、これを使用したことによって生じた問題については一切の責任を負いませんので予めご了承ください。

機能

下の動画のように、グラフをアクティブにし、マクロを実行するとあらかじめ設定していた体裁の散布図になる（マクロ実行は0:08~0:10）。
資料等に転載する際に大概必要となる、体裁や大きさをポチポチ整える作業を短縮できる。

グラフの体裁（凡例とか軸ラベルとかマーカーとか色とか）をワンタッチで整えるマクロ作ったった pic.twitter.com/YagkqpEy5o

— RyotaF (@fukuchanz40) March 3, 2021

使い方

グラフをクリック（アクティブに）して、マクロを実行する。
※あらかじめショートカットを登録しておくと楽。例えばCtrl+gとか（”グラフ”の”g”）。

プログラムの概要

変数"cht"に現在アクティブなグラフの名称を収納
→"cht"のチャートタイプを選択（折れ線付き散布図）
→グラフタイトルと外枠を消し、軸ラベルを追加
→.SeriesCollection.Countプロパティで系列の数を拾う
→それぞれの系列の色やプロットの形を設定する
→凡例の書式を設定
→グラフの大きさを拾う

基本的には全部ググって実装した。
VBA初心者である私が苦労した点は、アクティブなグラフ情報を拾う機能をどうVBAで書くかという点。
結果的に、アクティブなグラフ情報を拾う方法は、Yahoo知恵袋の素晴らしいアドバイスよりアイデアを拝借。
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q1139015571

拡張性

ユーザーフレンドリーな感じに書いてはいないが、コードの中で変数を変えることで下記の内容をカスタムできる。

• 散布図の種類（折れ線、平滑線の有無）
• プロットや線の配色
• 凡例の書式（書体や大きさ）
• グラフのサイズ

配色は適当に視認性がよさそうなものを入れている。また、7色目以降はとりあえず黒を入れた。
（RGBに変数を入れてグラデーショナルに変化させる…ということもできそう）

使用する際は、下記のコードをExcelファイルのVBEモジュールにコピー&ペーストしてください。
　　↓↓↓

コードを表示

Sub GraphEdit()
    Dim cht As String
    cht = ActiveChart.Parent.Name         'アクティブなグラフの名前を取得

    With ActiveSheet.ChartObjects(cht).Chart
        '---グラフの種類--------------------------------------------------------------------
        '   xlXYScatter                                  ：散布図
        '   xlXYScatterLines                          ：折れ線付き散布図
        '   xlXYScatterLinesNoMarkers         ：折れ線付き散布図（データマーカーなし）
        '   xlXYScatterSmooth                      ：平滑線付き散布図
        '   xlXYScatterSmoothNoMarkers     ：平滑線付き散布図（データマーカーなし）
        .ChartType = xlXYScatterLines
        
        .HasTitle = False       'グラフタイトルを表示しない
        .ChartArea.Format.Line.Visible = msoFalse
        .Axes(xlValue).HasTitle = True
        .Axes(xlCategory).HasTitle = True
        
        '---各系列に対する処理------------------------------------------------------------
        For i = 1 To .SeriesCollection.Count
            With ActiveSheet.ChartObjects(cht).Chart _
                .SeriesCollection(i)
                .MarkerSize = 5
                
                '~~＜マーカーの形と色＞~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
                If i = 1 Then
                    .MarkerForegroundColor = RGB(0, 51, 204)    '色1
                    .MarkerStyle = xlMarkerStyleCircle
                ElseIf i = 2 Then
                    .MarkerForegroundColor = RGB(153, 0, 204)    '色2
                    .MarkerStyle = xlMarkerStyleTriangle
                ElseIf i = 3 Then
                    .MarkerForegroundColor = RGB(204, 0, 51)    '色3
                    .MarkerStyle = xlMarkerStyleSquare
                ElseIf i = 4 Then
                    .MarkerForegroundColor = RGB(204, 153, 0)    '色4
                    .MarkerStyle = xlMarkerStyleDiamond
                ElseIf i = 5 Then
                    .MarkerForegroundColor = RGB(51, 204, 0)    '色5
                    .MarkerStyle = xlMarkerStyleSquare
                ElseIf i = 6 Then
                    .MarkerForegroundColor = RGB(0, 204, 153)    '色6
                    .MarkerStyle = xlMarkerStyleDiamond
                Else
                    .MarkerForegroundColor = RGB(10, 10, 10)    '色7以降
                    .MarkerStyle = xlMarkerStyleCircle
                End If
                '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
                
                .MarkerBackgroundColor = RGB(245, 245, 245)
                With .Format.Line
                    .Weight = 0.5
                    .DashStyle = msoLineSolid
                    
                '~~＜線の色＞~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
                    If i = 1 Then
                        .ForeColor.RGB = RGB(0, 51, 204)    '色1
                    ElseIf i = 2 Then
                        .ForeColor.RGB = RGB(153, 0, 204)    '色2
                    ElseIf i = 3 Then
                        .ForeColor.RGB = RGB(204, 0, 51)    '色3
                    ElseIf i = 4 Then
                        .ForeColor.RGB = RGB(204, 153, 0)    '色4
                    ElseIf i = 5 Then
                        .ForeColor.RGB = RGB(51, 204, 0)    '色5
                    ElseIf i = 6 Then
                        .ForeColor.RGB = RGB(0, 204, 153)    '色6
                    Else
                        .ForeColor.RGB = RGB(10, 10, 10)    '色7以降
                    End If
                '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
                 
                    .Transparency = 0
                End With
            End With
        Next
              
        '---凡例の書式--------------------------------------------------------------------
        .HasLegend = True   '凡例表示
        .Legend.IncludeInLayout = False
        .Legend.Left = .ChartArea.Width / 10
        .Legend.Top = .ChartArea.Height / 10
        .Legend.Font.Name = "游ゴシック"
        .Legend.Font.Size = 10 'フォントサイズ
        .Legend.Format.Line.ForeColor.RGB = RGB(30, 30, 30)
        With .Legend.Format.Fill
            .Visible = msoTrue
            .ForeColor.RGB = RGB(255, 255, 255)
        End With
        
    End With
    With ActiveSheet.ChartObjects(cht)
        '.Left = 200
        '.Top = 100
        .Width = 360
        .Height = 270
    End With
End Sub